CreateWindowEx ウィンドウ(コントロール)を作成
DestroyWindow CreateWindowExの解放
InitCommonControls コモンコントロールのダイナミックリンクライブラリ(DLL)に含まれている、特定のコモンコントロールクラスを登録
SendMessage ウィンドウにメッセージを送信
SetWindowPos ウィンドウのサイズ、位置、および Z オーダーを設定
　

'================================================================
'= ツールチップの作成(�U)
'=    (ToolTip2.bas)
'================================================================
#include "Windows.bi"

Type RECT
    Left   As Long
    Top    As Long
    Right  As Long
    Bottom As Long
End Type

Type TOOLINFO
    cbSize   As Long
    uFlags   As Long
    hwnd     As Long
    uId      As Long
    rc       As RECT
    hInst    As Long
    lpszText As Long
    lParam   As Long
End Type

' ウィンドウ（コントロール）を作成
Declare Function Api_CreateWindowEx& Lib "user32" Alias "CreateWindowExA" (ByVal ExStyle&, ByVal ClassName$, ByVal WinName$, ByVal Style&, ByVal x&, ByVal y&, ByVal nWidth&, ByVal nHeight&, ByVal Parent&, ByVal Menu&, ByVal Instance&, ByVal Param&)

' ウィンドウのサイズ、位置、および Z オーダーを設定
Declare Function Api_SetWindowPos& Lib "user32" Alias "SetWindowPos" (ByVal hWnd&, ByVal hWndInsertAfter&, ByVal X&, ByVal Y&, ByVal CX&, ByVal CY&, ByVal uFlags&)

' ウィンドウにメッセージを送信。この関数は、指定したウィンドウのウィンドウプロシージャが処理を終了するまで制御を返さない
Declare Function Api_SendMessage& Lib "user32" Alias "SendMessageA" (ByVal hWnd&, ByVal wMsg&, ByVal wParam&, lParam As Any)

' ウィンドウのクライアント領域の座標を取得
Declare Function Api_GetClientRect& Lib "user32" Alias "GetClientRect" (ByVal hWnd&, lpRect As RECT)

' CreateWindowExの解放
Declare Function Api_DestroyWindow& Lib "user32" Alias "DestroyWindow" (ByVal hWnd&)

#define TOOLTIPS_CLASSA "tooltips_class32"
#define TTF_IDISHWND &H1                'uIdメンバは、ツールのウィンドウハンドル
#define TTF_CENTERTIP &H2               'チップをツールの中心に表示
#define TTF_SUBCLASS &H10               'ツールをサブクラス化してメッセージを取得
#define TTM_ADDTOOL &H404               '(WM_USER+4)ツールの追加登録
#define TTS_BALLOON &H40                'バルーンチップを作る

Var Shared hWnd As Long
Var Shared flag As Integer

Var Shared Button1 As Object
Var Shared Check1 As Object

Button1.Attach GetDlgItem("Button1") : Button1.SetFontSize 14
Check1.Attach GetDlgItem("Check1") : Check1.SetFontSize 14

'================================================================
'=
'================================================================
Declare Sub ToolTip ()
Sub ToolTip()
    Var ti As TOOLINFO
    Var Ret As Long

    ti.cbSize = Len(ti)
    flag = Check1.GetCheck
    If flag = 0 Then
        ti.uFlags = TTF_IDISHWND Or TTF_SUBCLASS
    Else
        ti.uFlags = TTF_IDISHWND Or TTF_SUBCLASS Or TTF_CENTERTIP
    End If
    ti.hwnd = GethWnd
    ti.hinst = GethInst
    ti.uid = Button1.GethWnd
    ti.lpszText = StrAdr("APIで作成したToolTip" & Chr$(0))

    hWnd = Api_CreateWindowEx(0, TOOLTIPS_CLASSA, "", TTS_BALLOON, 0, 0, 0, 0, 0, 0, 0, 0)

    Ret = Api_SendMessage(hWnd, TTM_ADDTOOL, 0, ti)
End Sub

'================================================================
'=
'================================================================
Declare Sub DestroyTP ()
Sub DestroyTP()
    Var Ret As Long

    Ret = Api_DestroyWindow(hWnd)
End Sub

'================================================================
'=
'================================================================
Declare Sub MainForm_Start edecl ()
Sub MainForm_Start()
    ToolTip
End Sub

'================================================================
'=
'================================================================
Declare Sub Check1_on edecl ()
Sub Check1_on()
    DestroyTP
    ToolTip
End Sub

'================================================================
'=
'================================================================
Declare Sub MainForm_QueryClose edecl ()
Sub MainForm_QueryClose()
    DestroyTP
End Sub

'================================================================
'=
'================================================================
While 1
    WaitEvent
Wend
Stop
End